[arch-commits] Commit in (10 files)

[Jan Steffens]

    Date: Saturday, September 10, 2011 @ 07:03:31
  Author: heftig
Revision: 137661

add g-d and tracker

Added:
  gnome-documents/
  gnome-documents/repos/
  gnome-documents/trunk/
  gnome-documents/trunk/PKGBUILD
  gnome-documents/trunk/gnome-documents.install
  tracker/
  tracker/repos/
  tracker/trunk/
  tracker/trunk/PKGBUILD
  tracker/trunk/tracker.install

-----------------------------------------------+
 gnome-documents/trunk/PKGBUILD                |   34 +++++++++++++
 gnome-documents/trunk/gnome-documents.install |   13 +++++
 tracker/trunk/PKGBUILD                        |   59 ++++++++++++++++++++++++
 tracker/trunk/tracker.install                 |   13 +++++
 4 files changed, 119 insertions(+)

Added: gnome-documents/trunk/PKGBUILD
===================================================================
--- gnome-documents/trunk/PKGBUILD	                        (rev 0)
+++ gnome-documents/trunk/PKGBUILD	2011-09-10 11:03:31 UTC (rev 137661)
@@ -0,0 +1,34 @@
+# $Id$
+# Maintainer: Jan "heftig" Steffens <jan.steffens at gmail.com>
+
+pkgname=gnome-documents
+pkgver=0.1.91
+pkgrel=1
+pkgdesc="Documents Manager for GNOME"
+arch=(i686 x86_64)
+url="http://www.gnome.org"
+license=('GPL')
+groups=('gnome-extra')
+depends=('clutter-gtk' 'evince' 'gobject-introspection' 'gtk3' 'gnome-desktop'
+         'gnome-online-accounts' 'libgdata' 'tracker')
+makedepends=('intltool' 'vala')
+install=gnome-documents.install
+source=(http://download.gnome.org/sources/$pkgname/0.1/$pkgname-$pkgver.tar.xz)
+sha256sums=('b2180d86f4c162903d2e30300271f6f03b6bc351c0addb664b7ba04341c2f3b6')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/gnome-documents
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et:


Property changes on: gnome-documents/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
   + Id

Added: gnome-documents/trunk/gnome-documents.install
===================================================================
--- gnome-documents/trunk/gnome-documents.install	                        (rev 0)
+++ gnome-documents/trunk/gnome-documents.install	2011-09-10 11:03:31 UTC (rev 137661)
@@ -0,0 +1,13 @@
+post_install() {
+  usr/bin/glib-compile-schemas usr/share/glib-2.0/schemas
+  update-desktop-database -q
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}

Added: tracker/trunk/PKGBUILD
===================================================================
--- tracker/trunk/PKGBUILD	                        (rev 0)
+++ tracker/trunk/PKGBUILD	2011-09-10 11:03:31 UTC (rev 137661)
@@ -0,0 +1,59 @@
+# $Id$
+# Maintainer: Jan "heftig" Steffens <jan.steffens at gmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Alexander Fehr <pizzapunk gmail com>
+
+pkgname=tracker
+pkgver=0.12.0
+pkgrel=1
+pkgdesc="Powerful object database, tag/metadata database, search tool and indexer"
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('libgee' 'libgnome-keyring' 'upower' 'libexif' 'exempi' 'poppler-glib'
+         'libgsf' 'icu' 'enca' 'xdg-utils' 'networkmanager')
+makedepends=('gobject-introspection' 'intltool' 'giflib' 'gstreamer0.10-base'
+             'totem-plparser' 'evolution' 'taglib' 'nautilus' 'gnome-panel'
+             'firefox' 'thunderbird' 'libvorbis' 'flac')
+optdepends=('giflib: extractor for GIF data'
+            'gstreamer0.10-base: video extractor'
+            'totem-plparser: playlist support'
+            'evolution: Evolution email data miner'
+            'taglib: writeback for audio files'
+            'nautilus: nautilus-extension'
+            'libvorbis: Vorbis metadata extractor'
+            'flac: FLAC metadata extractor'
+            'firefox: Firefox data miner extension'
+            'thunderbird: Thunderbird data miner extension'
+            'gnome-panel: tracker-search-bar')
+provides=('libtracker')
+url="http://www.gnome.org"
+groups=('gnome-extra')
+options=('!libtool' '!emptydirs')
+install=tracker.install
+source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
+sha256sums=('6819b5fbbcaa14ac004759e4b25962f8ef36f2c4b37908a32fcf6d7a22e5b261')
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  _ffdir=/usr/lib/firefox-6.0.2/extensions
+  _tbdir=/usr/lib/thunderbird-6.0.2/extensions
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/tracker \
+    --disable-unit-tests \
+    --enable-libflac \
+    --enable-libvorbis \
+    --with-firefox-plugin-dir=$_ffdir \
+    --with-thunderbird-plugin-dir=$_tbdir
+
+  make
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+}


Property changes on: tracker/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
   + Id

Added: tracker/trunk/tracker.install
===================================================================
--- tracker/trunk/tracker.install	                        (rev 0)
+++ tracker/trunk/tracker.install	2011-09-10 11:03:31 UTC (rev 137661)
@@ -0,0 +1,13 @@
+post_install() {
+  usr/bin/glib-compile-schemas usr/share/glib-2.0/schemas
+  update-desktop-database -q
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}