# $Id: $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

pkgname=lib32-qtcurve-qt4
pkgver=1.5.2
pkgrel=1
arch=('x86_64')
license=('GPL')
pkgdesc='A configurable set of widget styles for KDE and Gtk (32 bit)'
url='http://www.kde-look.org/content/show.php?content=40492'
depends=('lib32-qt')
makedepends=('cmake' 'automoc4' 'gcc-multilib')
source=("http://craigd.wikispaces.com/file/view/QtCurve-KDE4-${pkgver}.tar.bz2")
md5sums=('6fc73762101a91a09b1359eb5b2689aa')

build() {
	export CFLAGS="-m32 $CFLAGS"
	export CXXFLAGS="-m32 $CXXFLAGS"
	export LDFLAGS="-m32 $LDFLAGS"
	export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
	cd $srcdir
	mkdir build
	cd build
	cmake ../QtCurve-KDE4-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DQTC_QT_ONLY=true \
		-DQT_PLUGINS_DIR=/usr/lib32/qt/plugins
	make
}

package() {
	cd $srcdir/build
	make DESTDIR=$pkgdir install
}
