[arch-commits] Commit in python-oauthlib/repos (community-any community-any/PKGBUILD)

[Massimiliano Torromeo]

    Date: Thursday, February 21, 2013 @ 14:58:23
  Author: mtorromeo
Revision: 84669

archrelease: copy trunk to community-any

Added:
  python-oauthlib/repos/community-any/
  python-oauthlib/repos/community-any/PKGBUILD
    (from rev 84668, python-oauthlib/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-oauthlib/repos/community-any/PKGBUILD (from rev 84668, python-oauthlib/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2013-02-21 13:58:23 UTC (rev 84669)
@@ -0,0 +1,44 @@
+# $Id$
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgbase=python-oauthlib
+pkgname=(python-oauthlib python2-oauthlib)
+pkgver=0.3.7
+pkgrel=1
+_libname=oauthlib
+pkgdesc="A generic, spec-compliant, thorough implementation of the OAuth request-signing logic"
+arch=(any)
+url="https://github.com/idangazit/oauthlib"
+license=('BSD')
+source=(http://pypi.python.org/packages/source/${_libname:0:1}/$_libname/$_libname-$pkgver.tar.gz)
+makedepends=(python-distribute python2-distribute)
+
+build() {
+	cd "$srcdir/$_libname-$pkgver"
+	
+	rm -rf ../buildpy3; mkdir ../buildpy3
+	python setup.py build -b ../buildpy3
+	
+	rm -rf ../buildpy2; mkdir ../buildpy2
+	python2 setup.py build -b ../buildpy2
+}
+
+package_python-oauthlib() {
+	depends=(python-rsa)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy3 build
+	python setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_python2-oauthlib() {
+	depends=(python2-rsa)
+	
+	cd "$srcdir/$_libname-$pkgver"
+	rm -rf build; ln -s ../buildpy2 build
+	python2 setup.py install --skip-build -O1 --root="$pkgdir"
+	install -m0644 -D "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+sha256sums=('12b8fb9fa02a531c412bdc0fcb3a214e3da8c4075f19d6ca2c6d1a3636d2a000')